mirror of
https://github.com/Suwayomi/Tachidesk.git
synced 2025-12-10 06:42:07 +01:00
00f5652db9
* Use JDK 25 to build and include in releases * Set Jvm Targets in BuildSrc * Put JvmTarget in libs.versions.toml * Maybe this will work for Zulu * Use LTS java version
61 lines
1.7 KiB
Kotlin
61 lines
1.7 KiB
Kotlin
import org.jetbrains.kotlin.gradle.dsl.JvmTarget
|
|
import org.jetbrains.kotlin.gradle.tasks.KotlinJvmCompile
|
|
import org.jlleitschuh.gradle.ktlint.KtlintExtension
|
|
import org.jlleitschuh.gradle.ktlint.KtlintPlugin
|
|
|
|
plugins {
|
|
alias(libs.plugins.kotlin.jvm) apply false
|
|
alias(libs.plugins.kotlin.serialization) apply false
|
|
alias(libs.plugins.ktlint) apply false
|
|
alias(libs.plugins.buildconfig) apply false
|
|
alias(libs.plugins.download)
|
|
alias(libs.plugins.kotlin.multiplatform) apply false
|
|
alias(libs.plugins.moko) apply false
|
|
alias(libs.plugins.jte) apply false
|
|
}
|
|
|
|
allprojects {
|
|
group = "suwayomi"
|
|
|
|
version = "1.0"
|
|
|
|
repositories {
|
|
mavenCentral()
|
|
google()
|
|
maven("https://github.com/Suwayomi/Suwayomi-Server/raw/android-jar/")
|
|
maven("https://jitpack.io")
|
|
maven("https://jogamp.org/deployment/maven")
|
|
}
|
|
}
|
|
|
|
subprojects {
|
|
plugins.withType<JavaPlugin> {
|
|
extensions.configure<JavaPluginExtension> {
|
|
val javaVersion = JavaVersion.toVersion(libs.versions.jvmTarget.get())
|
|
sourceCompatibility = javaVersion
|
|
targetCompatibility = javaVersion
|
|
}
|
|
}
|
|
|
|
plugins.withType<KtlintPlugin> {
|
|
extensions.configure<KtlintExtension>("ktlint") {
|
|
version.set(libs.versions.ktlint.get())
|
|
filter {
|
|
exclude("**/generated/**")
|
|
}
|
|
}
|
|
}
|
|
|
|
tasks {
|
|
withType<KotlinJvmCompile> {
|
|
if (plugins.hasPlugin(KtlintPlugin::class)) {
|
|
dependsOn("ktlintFormat")
|
|
}
|
|
compilerOptions {
|
|
jvmTarget = JvmTarget.fromTarget(libs.versions.jvmTarget.get())
|
|
freeCompilerArgs.add("-Xcontext-receivers")
|
|
}
|
|
}
|
|
}
|
|
}
|